Script VBS d'installation / mise à jour de FusionInventory-2.2.x

[IP OUEST]

Ben tu peux faire un script autoit et le compiler si tu veux absolument un exe

C'est à dire ??

[maxime68]

Bonjour,

J'utilise ton script et il marche a merveille, merci.
Maintenant j'ai une centaine d'agent déployés.
Le problème c'est que je vais changer l'adresse de mon serveur, comment mettre à jour la nouvelle adresse dans les configs des agents déployés ?
Si je modifie l'adresse dans le script va t'il me mettre les agents a jour ? ( sa me parait trop simple).

[mips]

Si l'environemet est sous AD, les gpo sont tes amies.
@+

[ZenAdm]

Bonjour,

Voici ci-dessous un script original de Tomas Abad, que j'ai déjà utilisé et adapté pour effectuer des modifications de configuration. J'avais trouvé son "resource kit" quelque part sur la forge l'an dernier il me semble, mais je ne sais plus où...
Le principe : arrêter le service, modifier la base des registres, redémarrer le service.
On peut tout à fait utiliser les GPO pour effectuer le changement au démarrage des PC du domaine, comme avec mon script d'installation.

Code:

'
'
' Sociedad Imaginaria, S.I.
' Copyright (c) Jul 2011, SI
'
' Node Name:     susa.sociedad.imaginaria.es
' Service Name:  
' File Name:     update-config.vbs
' Symbolic Link:
' OS Name:       Microsoft Windows 7
'
' Author(s):     Tomas Abad <tabad@sescam.jccm.es>
'
'

'
'
' Purpose:
'     FusionInventory-Agent Update Configuration Params.
'
'

On Error Resume Next

'
' Variable definitions...
'
CertificateFile = "sica-cert.pem"
FusionInventoryAgentServer = "https://ecumene.sociedad.imaginaria.es/ocsinventory,https://ecumene.sociedad.imaginaria.es/glpi/plugins/fusioninventory/"

FusionInventoryDeploymentRepository = "\\susa.sociedad.imaginaria.es\ecumene$\resources-kit\fusioninventory\programs"
CertificateAuthorityDeploymentRepository = "\\susa.sociedad.imaginaria.es\ecumene$\resources-kit\certs"

'
' DO NOT TOUCH UNDER THIS LINE
'

Set WshShell = Wscript.CreateObject("Wscript.shell")

OsType = WshShell.RegRead("HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment\PROCESSOR_ARCHITECTURE")

ProgramFiles = WshShell.ExpandEnvironmentStrings("%ProgramFiles%")

FusionInventoryAgentServiceName="FusionInventory-Agent"
FusionInventoryAgentPath = ProgramFiles & "\FusionInventory-Agent"
FusionInventoryAgentCertificatePath = FusionInventoryAgentPath & "\certs"
FusionInventoryAgentRegistry = "HKLM\SOFTWARE\FusionInventory-Agent\"

' Extract current version from registry
if (OsType = "x86") then
    FusionInventoryAgentUninstallKey = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent\UninstallString"
    FusionInventoryAgentCurrentVersionKey = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent\DisplayVersion"
else
    FusionInventoryAgentUninstallKey = "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent\UninstallString"
    FusionInventoryAgentCurrentVersionKey = "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\FusionInventory Agent\DisplayVersion"
end if

' Update configuration params if agent is installed
FusionInventoryAgentUninstall = WshShell.RegRead(FusionInventoryAgentUninstallKey)
FusionInventoryAgentCurrentVersion = WshShell.RegRead(FusionInventoryAgentCurrentVersionKey)
if FusionInventoryAgentUninstall <> "" then
    Wscript.Echo "FusionInventory-Agent v" & FusionInventoryAgentCurrentVersion & " installed."
    Wscript.Echo "Updating configuration params. Please wait..."

    ' Parar servicio
    command = "SC STOP """ & FusionInventoryAgentServiceName & """"
    'Wscript.Echo "Running command: " & command
    WshShell.Run "CMD.EXE /C """ & command & """",0,True

    ' Retardo de seguridad de 5 segundos
    WScript.Sleep (5 * 1000)

    ' Establecer servidores
    if FusionInventoryAgentServer <> "" then
        FusionInventoryAgentKey = FusionInventoryAgentRegistry & "server"
        WshShell.RegWrite FusionInventoryAgentKey, FusionInventoryAgentServer, "REG_SZ"
    end if

    ' Establecer ruta absoluta del certificado
    if CertificateFile <> "" then
        FusionInventoryAgentKey = FusionInventoryAgentRegistry & "ca-cert-file"
        WshShell.RegWrite FusionInventoryAgentKey, FusionInventoryAgentCertificatePath & "\" & CertificateFile, "REG_SZ"
    end if

    ' Desactivar depuracion
    'FusionInventoryAgentKey = FusionInventoryAgentRegistry & "debug"
    'WshShell.RegWrite FusionInventoryAgentKey, 0, "REG_SZ"

    ' Activar comprobacion del certificado
    'FusionInventoryAgentKey = FusionInventoryAgentRegistry & "no-ssl-check"
    'WshShell.RegWrite FusionInventoryAgentKey, 0, "REG_SZ"

    ' Desactivar inventario local por parte del usuario
    'FusionInventoryAgentKey = FusionInventoryAgentRegistry & "rpc-trust-localhost"
    'WshShell.RegWrite FusionInventoryAgentKey, 0, "REG_SZ"

    ' Activar analisis de directorio HOME
    'FusionInventoryAgentKey = FusionInventoryAgentRegistry & "scan-homedirs"
    'WshShell.RegWrite FusionInventoryAgentKey, 1, "REG_SZ"

    ' Crear directorio de certificados
    'command = "MKDIR """ & FusionInventoryAgentCertificatePath & """"
    'Wscript.Echo "Running command: " & command
    'WshShell.Run "CMD.EXE /C """ & command & """",0,True

    ' Copiar certificado
    if CertificateFile <> "" then
        command = "COPY """ & CertificateAuthorityDeploymentRepository & "\" & CertificateFile & """ """ & FusionInventoryAgentCertificatePath & """ /Y"
        'Wscript.Echo "Running command: " & command
        WshShell.Run "CMD.EXE /C """ & command & """",0,True
    end if

    ' Iniciar servicio
    command = "SC START """ & FusionInventoryAgentServiceName & """"
    'Wscript.Echo "Running command: " & command
    WshShell.Run "CMD.EXE /C """ & command & """",0,True
else
    Wscript.Echo "FusionInventory-Agent is not installed in this computer."
end if

[goneri]

Je viens d'importer ce script dans le dépôt git de l'agent :
https://github.com/fusinv/fusioninventor...ib/windows

J'ai fait ça car ça devenait vraiment compliquer de trouver la version de référence. Je le supprimerai du Wiki dans quelques jours . Donc je vous invite a faire des patches par rapport à la version Git maintenant \o/

[c.lamy]

Je viens d'importer ce script dans le dépôt git de l'agent :
https://github.com/fusinv/fusioninventor...ib/windows

J'ai fait ça car ça devenait vraiment compliquer de trouver la version de référence. Je le supprimerai du Wiki dans quelques jours . Donc je vous invite a faire des patches par rapport à la version Git maintenant \o/

Bonjour,

voilà que j'utilise le script depuis plusieurs mois. Il fonctionne à merveille, j'avais déjà upgradé le lien car la version n'étais plus disponible sur le site. Je me suis rendu compte ce matin, qu'il n'y a plus aucune version disponible sur le site (http://freefr.dl.sourceforge.net/project....x/2.3.16/).

Est-il possible de mettre à jour les dépôts ?

Merci

[mla]

En fait l'installeur a changé (plus le même nom, version 32 et 64 bits, clés de registre qui change etc...) donc le script présenté ici ne fonctionne plus
https://raw.githubusercontent.com/fusinv...oyment.vbs

[c.lamy]

Comment définir le mode debug à 2 ?

j'ai essayé de rajouter l'option dans le script mais depuis il ne fonctionne plus.
SetupOptions = "/acceptlicense /debug /runnow /server='http://glpi.yourcompany.com/glpi/plugins/fusioninventory/' /S"